Windows Seven "E"(uropéen)

[Richard]

Salut,

 

Comme je l'avais dit, j'ai pondu un petit script + tutorial pour faciliter la vie des débutants sur la version Windows Seven "E". Pour mémoire, la seule différence avec la version Seven "normale" est qu'elle n'aura aucun navigateur intégré (pas d'Internet Explorer). Du coup, de 2 choses l'une :

 

- soit vous avez prévu, et vous avez Firefox (ou autre) sur une clef USB

 

- soit vous utilisez un client FTP pour le télécharger et l'installer en direct

 

Le script n'aura finalement que peu d'utilité, dans le sens où il faut déjà avoir les fichiers quelque part pour pouvoir les lancer sous "Seven E", mais cela reste toujours plus facile que de le taper à la main sous l'interpréteur. Et puis, ça m'amusait de me replonger dans MSDOS (rhâlala, que c'est vieux...) pour quelques instants.

 

A télécharger (save as) :

Fichier CMD / Fichier FTP

 

Il suffit alors de mettre les 2 fichiers au même endroit, et de lancer le fichier "cmd". Cela téléchargera Firefox 3.5, avant de l'installer. La seule nécessité étant de disposer d'une connexion à internet.

 

 

Sinon, les commandes pour télécharger et installer manuellement les fichiers via le client FTP inclus dans XP/Vista/Seven peuvent toujours être intéressantes à connaître, d'autant qu'elles restent très simples. Petit pas-à-pas :

 

Ouvrir l'interpréteur de commandes

"menu démarrer / exécuter" ou "menu démarrer / rechercher" et taper "cmd".

 

Dans l'interpréteur de commandes, voici les actions à lancer :

 

ftp -A 204.152.184.113

 

binary

 

cd /pub/mozilla.org/firefox/releases/3.5/win32/fr/

 

get "Firefox Setup 3.5.exe"

 

close

 

bye

 

"Firefox Setup 3.5.exe"

 

exit

 

Explication de texte :

- on lance l'application FTP + connexion en anonyme au serveur FTP de Mozilla.

- on passe en mode binaire, pour l'échange d'exécutable

- on se positionne dans le bon répertoire

- on télécharge le fichier utile

- on ferme la connexion au serveur

- on quitte le client FTP

- on lance l'exécutable d'installation de Firefox

- on quitte l'interpréteur

 

Et voilà.

[SEB]

Sympa ce petit script :)

 

Testé à l'instant sous XP. Ca marche :)

 

 

edit :

 

posté en news ;)

[EmpereurZorg]

Voilà un tout en un.

Modifications :

- un seul fichier batch

- transferts ftp dans le répertoire temporaire

- affiche un log uniquement en cas d'erreur ftp

- si on n'efface pas l'exe, il se retrouve dans le répertoire du batch

 

@echo off

set name=Firefox Setup 3.5.exe

echo -----------------------------------------------------------
echo  Veuillez patienter pendant le telechargement du fichier !
echo -----------------------------------------------------------

echo OPEN 204.152.184.113 21>%temp%\firefox.ftp
echo. >>%temp%\firefox.ftp
echo USER anonymous anonymous>>%temp%\firefox.ftp
echo BINARY>>%temp%\firefox.ftp
echo LCD %temp%>>%temp%\firefox.ftp
echo CD /pub/mozilla.org/firefox/releases/3.5/win32/fr/>>%temp%\firefox.ftp
echo GET "%name%">>%temp%\firefox.ftp
echo CLOSE>>%temp%\firefox.ftp
echo bye>>%temp%\firefox.ftp

ftp -s:%temp%\firefox.ftp >%temp%\firefox.log 2>NUL

del %temp%\firefox.ftp>NUL

type %temp%\firefox.log | find /i "226 File send OK"
if errorlevel 1 (
cls
echo -----------------------------------------------------------
echo !! Erreur pendant le transfert FTP, voir fichier de log  !!
echo -----------------------------------------------------------
notepad %temp%\firefox.log
del %temp%\firefox.log
exit
)

cls
echo -----------------------------------------------------------
echo Appuyer sur une touche pour installer Firefox
echo -----------------------------------------------------------
pause>NUL
"%temp%\%name%"

cls
echo -----------------------------------------------------------
echo Effacer le fichier d'installation (O/N)
echo -----------------------------------------------------------

set /p ERASE=
if /i "%ERASE%"=="n" (move "%temp%\%name%" .) else (del "%temp%\%name%")
del %temp%\firefox.log

exit

[SEB]

Merci EmpereurZorg pour cette nouvelle version du script :)

[Richard]

Ah oui ! Joli !

 

Je ne me souvenais plus d'un tas de trucs, ça permet également de se rafraîchir la mémoire. A la limite, il manquerait juste une menu au départ pour sélectionner la langue souhaitée (FR, EN, ES, etc.), et lui attribuer le chemin dans la variable, mais c'est vraiment pour pinailler (pareil, je ne me souviens plus comment on procède).

 

Seb, tu devrais reprendre la version de EmpereurZorg (save as), bien mieux écrite, avec des boucles de vérifications et autres variables utiles.

:)

[Axtrane]

Si je dis pas de bêtises, si vous rajoutez un "hash" dans les commandes ftp, ça permet de suivre si ça télécharge bien ....... parce que des fois on reste devant et on se demande s'il se passe quelque chose .....